Buildx fix

nomad-job.hcl

@@ -0,0 +1,139 @@
+job "dolibarr" {
+  datacenters = ["dc1"]
+  type        = "service"
+
+  group "dolibarr" {
+    count = 1
+
+    constraint {
+      attribute = "${node.unique.name}"
+      value     = "autobox.i80.dk"
+    }
+
+    network {
+      mode = "bridge"
+      port "http" {
+        to = 80
+      }
+    }
+
+    volume "dolibarr-db" {
+      type      = "host"
+      source    = "dolibarr-db"
+      read_only = false
+    }
+
+    volume "dolibarr-documents" {
+      type      = "host"
+      source    = "dolibarr-documents"
+      read_only = false
+    }
+
+    task "mariadb" {
+      driver = "docker"
+
+      config {
+        image = "mariadb:10.11"
+      }
+
+      volume_mount {
+        volume      = "dolibarr-db"
+        destination = "/var/lib/mysql"
+      }
+
+      template {
+        data = <<EOH
+MARIADB_ROOT_PASSWORD="{{ key "dolibarr/db_root_password" }}"
+MARIADB_DATABASE="dolibarr"
+MARIADB_USER="dolibarr"
+MARIADB_PASSWORD="{{ key "dolibarr/db_password" }}"
+EOH
+        destination = "secrets/mariadb.env"
+        env         = true
+      }
+
+      resources {
+        cpu    = 256
+        memory = 512
+      }
+
+      restart {
+        attempts = 5
+        delay    = "15s"
+        interval = "2m"
+        mode     = "fail"
+      }
+    }
+
+    task "app" {
+      driver = "docker"
+
+      config {
+        image = "dolibarr/dolibarr:latest"
+        ports = ["http"]
+      }
+
+      volume_mount {
+        volume      = "dolibarr-documents"
+        destination = "/var/www/documents"
+      }
+
+      template {
+        data = <<EOH
+DOLI_DB_PASSWORD="{{ key "dolibarr/db_password" }}"
+DOLI_ADMIN_PASSWORD="{{ key "dolibarr/admin_password" }}"
+EOH
+        destination = "secrets/dolibarr.env"
+        env         = true
+      }
+
+      env {
+        DOLI_DB_HOST      = "127.0.0.1"
+        DOLI_DB_PORT      = "3306"
+        DOLI_DB_NAME      = "dolibarr"
+        DOLI_DB_USER      = "dolibarr"
+        DOLI_URL_ROOT     = "https://portal.i80.dk"
+        DOLI_ADMIN_LOGIN  = "admin"
+        DOLI_INSTALL_AUTO = "1"
+        DOLI_COMPANY_NAME = "i80"
+      }
+
+      resources {
+        cpu    = 512
+        memory = 512
+      }
+
+      restart {
+        attempts = 5
+        delay    = "20s"
+        interval = "3m"
+        mode     = "fail"
+      }
+
+      service {
+        name     = "dolibarr"
+        port     = "http"
+        provider = "consul"
+
+        tags = [
+          "traefik.enable=true",
+          "traefik.http.routers.dolibarr.rule=Host(`portal.i80.dk`)",
+          "traefik.http.routers.dolibarr.tls=true",
+          "traefik.http.routers.dolibarr.tls.certresolver=letsencrypt",
+        ]
+
+        check {
+          type     = "http"
+          path     = "/"
+          interval = "30s"
+          timeout  = "10s"
+
+          check_restart {
+            limit = 3
+            grace = "60s"
+          }
+        }
+      }
+    }
+  }
+}